# Pony.fm - A community for pony fan music.
# Copyright (C) 2015 Peter Deltchev
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU Affero General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Affero General Public License for more details.
#
# You should have received a copy of the GNU Affero General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

window.pfm.preloaders['tracks'] = [
    'tracks', '$state'
    (tracks) ->
        tracks.loadFilters()
]

module.exports = angular.module('ponyfm').controller "tracks", [
    '$scope', 'tracks', '$state', 'focus', 'meta'
    ($scope, tracks, $state, focus, meta) ->
        meta.setTitle('Browse Tracks')

        $scope.recentTracks = null
        $scope.query = tracks.mainQuery
        $scope.filters = tracks.filters
        $scope.isVocal = JSON.stringify($scope.query.filters.isVocal)
        $scope.order = JSON.stringify($scope.query.filters.sort)

        filterDropdown = (newVar, oldVar) ->
            if newVar instanceof Array && oldVar instanceof Array
                if 'any' in newVar
                    if !('any' in oldVar)
                        newVar = ['any']
                    else if newVar.length > oldVar.length
                        anyIndex = newVar.indexOf('any')
                        newVar.splice(anyIndex, 1)

        $scope.handleSingularDropdown = (filter, value) ->
            $scope.clearFilter filter
            $scope.setFilter filter, JSON.parse(value)

        $scope.filterDropdownAfterClose = (values, filter) ->
            $scope.clearFilter filter
            anyOption = 'any'

            if anyOption in values && values.length > 1
                anyIndex = values.indexOf(anyOption)
                values.splice(anyIndex, 1)

            for id in values
                if id != anyOption
                    if filter == 'isVocal'
                        $scope.setFilter filter, id
                    else
                        $scope.toggleListFilter filter, id

        $scope.$watch 'type', (newVar, oldVar) ->
            filterDropdown newVar, oldVar

        $scope.$watch 'showSongs', (newVar, oldVar) ->
            filterDropdown newVar, oldVar

        $scope.$watch 'genres', (newVar, oldVar) ->
            filterDropdown newVar, oldVar

        $scope.toggleListFilter = (filter, id) ->
            $scope.query.toggleListFilter filter, id
            $state.transitionTo 'content.tracks.list', {filter: $scope.query.toFilterString()}

        $scope.setFilter = (filter, value) ->
            $scope.query.setFilter filter, value
            $state.transitionTo 'content.tracks.list', {filter: $scope.query.toFilterString()}

        $scope.setListFilter = (filter, id) ->
            $scope.query.setListFilter filter, id
            $state.transitionTo 'content.tracks.list', {filter: $scope.query.toFilterString()}

        $scope.clearFilter = (filter) ->
            $scope.query.clearFilter filter
            $state.transitionTo 'content.tracks.list', {filter: $scope.query.toFilterString()}

        tracks.mainQuery.listen (searchResults) ->
            $scope.tracks = searchResults.tracks
            $scope.currentPage = parseInt(searchResults.current_page)
            $scope.totalPages = parseInt(searchResults.total_pages)
            delete $scope.nextPage
            delete $scope.prevPage

            $scope.nextPage = $scope.currentPage + 1 if $scope.currentPage < $scope.totalPages
            $scope.prevPage = $scope.currentPage - 1 if $scope.currentPage > 1
            $scope.allPages = [1..$scope.totalPages]

            # TODO: turn this into a directive
            # The actual first page will always be in the paginator.
            $scope.pages = [1]

            # This logic determines how many pages to add prior to the current page, if any.
            firstPage = Math.max(2, $scope.currentPage-3)
            $scope.pages = $scope.pages.concat [firstPage..$scope.currentPage] unless $scope.currentPage == 1

            pagesLeftToAdd = 8-$scope.pages.length

            lastPage = Math.min($scope.totalPages - 1, $scope.currentPage+1+pagesLeftToAdd)
            $scope.pages = $scope.pages.concat([$scope.currentPage+1..lastPage]) unless $scope.currentPage >= lastPage

            # The actual last page will always be in the paginator.
            $scope.pages.push($scope.totalPages) unless $scope.totalPages in $scope.pages

        $scope.pageSelectorShown = false

        $scope.gotoPage = (page) ->
            $state.transitionTo 'content.tracks.list', {filter: $state.params.filter, page: page}

        $scope.showPageSelector = () ->
            $scope.pageSelectorShown = true
            focus('#pagination-jump-destination')

        $scope.hidePageSelector = () ->
            $scope.pageSelectorShown = false


        $scope.jumpToPage = (inputPageNumber) ->
            $scope.gotoPage(inputPageNumber)

        $scope.$on '$destroy', -> tracks.mainQuery = tracks.createQuery()
]