mirror of
https://github.com/ch11ng/exwm.git
synced 2024-11-23 19:47:58 +01:00
7823eb988c
; This is an attempt to make (managed) X windows container-less, i.e. direct children of the root window. This is mainly to make EXWM compatible with third-party compositors. Other issues like wrong absolute position should also get resolved by the way. The workspace containers ("virtual roots") are also removed. However Emacs frames are still wrapped in containers to avoid unexpected stack reordering.
* exwm-cm.el: Make this module obsolete as EXWM supports third-party compositors now.
* exwm-core.el (exwm--container):
* exwm-floating.el (exwm-floating--set-floating)
(exwm-floating--unset-floating, exwm-floating-hide)
(exwm-floating--start-moveresize, exwm-floating--stop-moveresize)
(exwm-floating--do-moveresize, exwm-floating-move):
* exwm-input.el (exwm-input--update-focus):
* exwm-layout.el (exwm-layout--show, exwm-layout--hide)
(exwm-layout-set-fullscreen, exwm-layout-unset-fullscreen):
* exwm-manage.el (exwm-manage--manage-window, exwm-manage--unmanage-window)
(exwm-manage--kill-buffer-query-function, exwm-manage--kill-client):
* exwm-workspace.el (exwm-workspace--set-fullscreen, exwm-workspace-switch)
(exwm-workspace-move-window, exwm-workspace--add-frame-as-workspace)
(exwm-workspace--remove-frame-as-workspace): Make adaptions for container-less X windows.
* exwm-workspace.el (exwm-workspace--update-ewmh-props):
* exwm.el (exwm--init-icccm-ewmh, exwm--exit-icccm-ewmh): No longer use virtual roots.
* exwm-input.el (exwm-input--on-workspace-list-change)
(exwm-input--update-global-prefix-keys, exwm-input--init, exwm-input--exit): From now on global key bindings are grabbed on the root window so it's no long required to re-grab them each time the workspace list changes. As a result `exwm-input--on-workspace-list-change' and its corresponding references are discarded. It remains to be seen if this change will raise input focus issues.
* exwm-manage.el (exwm-manage--manage-window): Explicitly set the workspace for newly managed X windows.
* exwm-floating.el (exwm-floating--set-floating): Avoid implicit reference to the current workspace.
* exwm-core.el (exwm--set-geometry): New function for setting the geometry of an X window.
* exwm-layout.el (exwm-layout--resize-container): Replaced by `exwm-layout--resize-container'.
* exwm-core.el (exwm--guide-window): New global variable recording the guide X window.
* exwm.el (exwm--init-icccm-ewmh): Set it.
* exwm-input.el (exwm-input--post-init): New function containing staffs for initialization but should better get called after the event loop starts.
* exwm.el (exwm-init): Use it.
183 lines
7.9 KiB
EmacsLisp
183 lines
7.9 KiB
EmacsLisp
;;; exwm-randr.el --- RandR Module for EXWM -*- lexical-binding: t -*-
|
||
|
||
;; Copyright (C) 2015-2018 Free Software Foundation, Inc.
|
||
|
||
;; Author: Chris Feng <chris.w.feng@gmail.com>
|
||
|
||
;; This file is part of GNU Emacs.
|
||
|
||
;; GNU Emacs is free software: you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation, either version 3 of the License, or
|
||
;; (at your option) any later version.
|
||
|
||
;; GNU Emacs is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
||
|
||
;;; Commentary:
|
||
|
||
;; This module adds RandR support for EXWM. Currently it requires external
|
||
;; tools such as xrandr(1) to properly configure RandR first. This
|
||
;; dependency may be removed in the future, but more work is needed before
|
||
;; that.
|
||
|
||
;; To use this module, load, enable it and configure
|
||
;; `exwm-randr-workspace-output-plist' and `exwm-randr-screen-change-hook'
|
||
;; as follows:
|
||
;;
|
||
;; (require 'exwm-randr)
|
||
;; (setq exwm-randr-workspace-output-plist '(0 "VGA1"))
|
||
;; (add-hook 'exwm-randr-screen-change-hook
|
||
;; (lambda ()
|
||
;; (start-process-shell-command
|
||
;; "xrandr" nil "xrandr --output VGA1 --left-of LVDS1 --auto")))
|
||
;; (exwm-randr-enable)
|
||
;;
|
||
;; With above lines, workspace 0 should be assigned to the output named "VGA1",
|
||
;; staying at the left of other workspaces on the output "LVDS1". Please refer
|
||
;; to xrandr(1) for the configuration of RandR.
|
||
|
||
;; References:
|
||
;; + RandR (http://www.x.org/archive/X11R7.7/doc/randrproto/randrproto.txt)
|
||
|
||
;;; Code:
|
||
|
||
(require 'xcb-randr)
|
||
(require 'exwm-core)
|
||
|
||
(defvar exwm-randr-workspace-output-plist nil)
|
||
|
||
(defvar exwm-randr-refresh-hook nil
|
||
"Normal hook run when the RandR module just refreshed.")
|
||
|
||
(defvar exwm-workspace--fullscreen-frame-count)
|
||
(defvar exwm-workspace--list)
|
||
|
||
(declare-function exwm-workspace--count "exwm-workspace.el")
|
||
(declare-function exwm-workspace--set-fullscreen "exwm-workspace.el" (frame))
|
||
(declare-function exwm-workspace--update-workareas "exwm-workspace.el" ())
|
||
(declare-function exwm-workspace--show-minibuffer "exwm-workspace.el" ())
|
||
(declare-function exwm-workspace--set-desktop-geometry "exwm-workspace.el" ())
|
||
|
||
(defun exwm-randr--refresh ()
|
||
"Refresh workspaces according to the updated RandR info."
|
||
(let (output-name geometry output-plist default-geometry)
|
||
;; Query all outputs
|
||
(with-slots (config-timestamp outputs)
|
||
(xcb:+request-unchecked+reply exwm--connection
|
||
(make-instance 'xcb:randr:GetScreenResources
|
||
:window exwm--root))
|
||
(dolist (output outputs)
|
||
(with-slots (crtc connection name)
|
||
(xcb:+request-unchecked+reply exwm--connection
|
||
(make-instance 'xcb:randr:GetOutputInfo
|
||
:output output
|
||
:config-timestamp config-timestamp))
|
||
(setf output-name ;UTF-8 encoded
|
||
(decode-coding-string (apply #'unibyte-string name) 'utf-8))
|
||
(if (or (/= connection xcb:randr:Connection:Connected)
|
||
(= 0 crtc)) ;FIXME
|
||
(plist-put output-plist output-name nil)
|
||
(with-slots (x y width height)
|
||
(xcb:+request-unchecked+reply exwm--connection
|
||
(make-instance 'xcb:randr:GetCrtcInfo
|
||
:crtc crtc
|
||
:config-timestamp config-timestamp))
|
||
(setq geometry (make-instance 'xcb:RECTANGLE
|
||
:x x :y y
|
||
:width width :height height)
|
||
output-plist (plist-put output-plist output-name geometry))
|
||
(unless default-geometry ;assume the first output as primary
|
||
(setq default-geometry geometry)))))))
|
||
(exwm--log "(randr) outputs: %s" output-plist)
|
||
(when output-plist
|
||
(when exwm-workspace--fullscreen-frame-count
|
||
;; Not all workspaces are fullscreen; reset this counter.
|
||
(setq exwm-workspace--fullscreen-frame-count 0))
|
||
(dotimes (i (exwm-workspace--count))
|
||
(let* ((output (plist-get exwm-randr-workspace-output-plist i))
|
||
(geometry (lax-plist-get output-plist output))
|
||
(frame (elt exwm-workspace--list i)))
|
||
(unless geometry
|
||
(setq geometry default-geometry
|
||
output nil))
|
||
(set-frame-parameter frame 'exwm-randr-output output)
|
||
(set-frame-parameter frame 'exwm-geometry geometry)))
|
||
;; Update workareas.
|
||
(exwm-workspace--update-workareas)
|
||
;; Resize workspace.
|
||
(dolist (f exwm-workspace--list)
|
||
(exwm-workspace--set-fullscreen f))
|
||
;; Raise the minibuffer if it's active.
|
||
(when (and (active-minibuffer-window)
|
||
(exwm-workspace--minibuffer-own-frame-p))
|
||
(exwm-workspace--show-minibuffer))
|
||
;; Set _NET_DESKTOP_GEOMETRY.
|
||
(exwm-workspace--set-desktop-geometry)
|
||
(xcb:flush exwm--connection)
|
||
(run-hooks 'exwm-randr-refresh-hook))))
|
||
|
||
(defvar exwm-randr-screen-change-hook nil
|
||
"Normal hook run when screen changes.")
|
||
|
||
(defun exwm-randr--init ()
|
||
"Initialize RandR extension and EXWM RandR module."
|
||
(if (= 0 (slot-value (xcb:get-extension-data exwm--connection 'xcb:randr)
|
||
'present))
|
||
(error "[EXWM] RandR extension is not supported by the server")
|
||
(with-slots (major-version minor-version)
|
||
(xcb:+request-unchecked+reply exwm--connection
|
||
(make-instance 'xcb:randr:QueryVersion
|
||
:major-version 1 :minor-version 2))
|
||
(if (or (/= major-version 1) (< minor-version 2))
|
||
(error "[EXWM] The server only support RandR version up to %d.%d"
|
||
major-version minor-version)
|
||
;; External monitor(s) may already be connected.
|
||
(run-hooks 'exwm-randr-screen-change-hook)
|
||
(exwm-randr--refresh)
|
||
(xcb:+event exwm--connection 'xcb:randr:ScreenChangeNotify
|
||
(lambda (_data _synthetic)
|
||
(exwm--log "(RandR) ScreenChangeNotify")
|
||
(run-hooks 'exwm-randr-screen-change-hook)
|
||
(exwm-randr--refresh)))
|
||
;; (xcb:+event exwm--connection 'xcb:randr:Notify
|
||
;; (lambda (_data _synthetic)
|
||
;; (exwm--log "(RandR) Notify")
|
||
;; (exwm-randr--refresh)))
|
||
(xcb:+request exwm--connection
|
||
(make-instance 'xcb:randr:SelectInput
|
||
:window exwm--root
|
||
:enable xcb:randr:NotifyMask:ScreenChange
|
||
;; :enable (eval-when-compile
|
||
;; (logior
|
||
;; xcb:randr:NotifyMask:ScreenChange
|
||
;; xcb:randr:NotifyMask:OutputChange
|
||
;; xcb:randr:NotifyMask:OutputProperty
|
||
;; xcb:randr:NotifyMask:CrtcChange))
|
||
))
|
||
(xcb:flush exwm--connection)
|
||
(add-hook 'exwm-workspace-list-change-hook #'exwm-randr--refresh))))
|
||
;; Prevent frame parameters introduced by this module from being
|
||
;; saved/restored.
|
||
(dolist (i '(exwm-randr-output))
|
||
(push (cons i :never) frameset-filter-alist)))
|
||
|
||
(defun exwm-randr--exit ()
|
||
"Exit the RandR module."
|
||
(remove-hook 'exwm-workspace-list-change-hook #'exwm-randr--refresh))
|
||
|
||
(defun exwm-randr-enable ()
|
||
"Enable RandR support for EXWM."
|
||
(add-hook 'exwm-init-hook #'exwm-randr--init)
|
||
(add-hook 'exwm-exit-hook #'exwm-randr--exit))
|
||
|
||
|
||
|
||
(provide 'exwm-randr)
|
||
|
||
;;; exwm-randr.el ends here
|